[SOLVED] Cannot convert mixtape/street tag to Mixtape

MusicBrainz Picard
, , , ,
1

As the title states, I am trying to organize my folder structure with Singles, EPs, Albums, Mixtapes, and etc.

Currently using this code:

$if2(%_artists_album_primary_cred%,%artist%)
/
$if($eq(%releasetype%,album), Albums/,
  $if($eq(%releasetype%,single), Singles/,
    $if($eq(%releasetype%,ep), EPs/,
      $if($eq(%releasetype%,broadcast), FM/,
        $if($eq(%releasetype%,other), Other/,
          $if($inmulti(%releasetype%,dj-mix), DJ Mix/,
            $if($inmulti(%releasetype%,remix), Remix/,
              $if($inmulti(%releasetype%,soundtrack), OST/,
                $if($inmulti(%releasetype%,live), Live/,
                  $if($inmulti(%releasetype%,mixtape/street), Mixtape/,
                    $if($inmulti(%releasetype%,compilation), Compilation/,)
                  )
                )
              )
            )
          )
        )
      )
    )
  )
)
$if($if2(%_date%,%originalyear%,%originaldate%),[$left($if2(%_date%,%originalyear%,%originaldate%),4)] ,)
$if(%albumartist%,%album%,)
/
$if2(%_artists_album_primary_cred%,%artist%) - 
$if($if2(%_date%,%originalyear%,%originaldate%),[$left($if2(%_date%,%originalyear%,%originaldate%),4)] $if(%albumartist%,%album%,) - ,)
$if($gt(%totaldiscs%,1),%discnumber%,)
$if($and(%albumartist%,%tracknumber%),$num(%tracknumber%,2) - ,)
$if($if2(%_albumartists%,%artist%,) - ,)%_titleForFilename%

However this particular line $if($inmulti(%releasetype%,mixtape/street), Mixtape/, is not recognized at all. All the other tags work in the script and recognizes singles, albums, OSTs.

I have no idea why it’s working. Any help would be much appreciated.

2

Inside file naming scripts slashes in variable values get replaced with underscores, as slashes are used as directory separators.

That means the code snippet must be $if($inmulti(%releasetype%,mixtape_street), Mixtape/

4 Likes
3

Thank you so much! That worked! I can’t tell you how many threads I came across with code written exactly like that and not one person mentioned replacing the slash with an underscore.

2 Likes