Edit: So I don’t think there are any variables I can use to say, if this put images here. The only image related variables I can find are coverart_maintype, coverart_types, and coverart_comment.
Am I right in thinking that the Cover Art tab in the options is the only place I can tell Picard to do something with images, and that any path will always be relative to the file being read? Maybe I can suss something out.
Here’s my rename script anyway:
$noop(
Replace ... with …
)
$set(title,$replace(%title%,...,…))
$set(album,$replace(%album%,...,…))
$set(discsubtitle,$replace(%discsubtitle%,...,…))
$if(%discsubtitle%,$set(~id3:TXXX:discsubtitle,%discsubtitle%))
$noop(
Organise files by filetype.
$upper(%_extension%)/
)
$noop(
Organise files under Album Artist
)
%albumartist%/
$noop(
Organise promotional releases away from official releases
)
$if($in(%releasestatus%,promo),
Promotional/
)
$noop(
Organise release types
)
$if(%_secondaryreleasetype%,
$title(%_secondaryreleasetype%),
$if($lt($len(%_primaryreleasetype%),3),
$upper(%_primaryreleasetype%),
$title(%_primaryreleasetype%)
)
)/
$noop(
Format release main directory
)
%originalyear% -
%albumartist% —
%album%
\(
$if(%date%,%date%,missing-date)
$if(%label%,
$if($not($in(%label%,
[no label])),\,
%label%
),
)
\)
$noop(
Include information on release format
)
\(
$if($lt(%totaldiscs%,2),
$noop(
Single disc
)
$if($in(%media%,Digital),
Digital$if($gt(%_bits_per_sample%,16), @ %_bits_per_sample%bit,)$if($gt(%_sample_rate%,44100), $div(%_sample_rate%,1000)kHz,)$if(%_releasecomment%, • %_releasecomment%,),
%media%\,
),
$noop(
Multi disc
)
$if($in(%media%,Digital),
Digital$if($gt(%_bits_per_sample%,16), @ %_bits_per_sample%bit,)$if($gt(%_sample_rate%,44100), $div(%_sample_rate%,1000)kHz,)$if(%_releasecomment%, • %_releasecomment%,),
$if($is_complete(),
$if($if(%media%,CD),
%totaldiscs%×%media%\, ,
%media%\,
),
%media%\,
)
)
)
$noop(
Where was release issued?
)
$if($not($in(%media%,Digital)),
$if($in(%releasecountry%,XW),
Worldwide,
$if($in(%releasecountry%,XE),
Europe,%releasecountry%)))
\)
$noop(
If there is a cat number, include it at the end of the main release directory name
)
$if(%catalognumber%,[$upper(%catalognumber%)],)/
$noop(
Sort discs into subdirectories
)
$if($is_complete(),
$noop(
If is complete
Helps deal with releases where the end disc(s) are DVDs etc, and not present in sorted files.
)
$if($gte(%totaldiscs%,2),
$noop(
Prepend release format to folder, if format not digital
)
$if($not($in(%media%,Digital)),
%media% ,
)
)
$if($gte(%totaldiscs%,2),
$pad(%discnumber%,2,0). ,)
$if($gte(%totaldiscs%,2),
$if(%discsubtitle%,
%discsubtitle%/,
%album%/
)
),
$noop(
If is incomplete
)
$if($gte(%totaldiscs%,3),
$noop(
Prepend release format to folder, if format not digital
)
$if($not($in(%media%,Digital)),
%media% ,
)
)
$if($gte(%totaldiscs%,3),
$pad(%discnumber%,2,0). ,)
$if($gte(%totaldiscs%,3),
$if(%discsubtitle%,
%discsubtitle%/,
%album%/
)
)
)
$noop(
Use vinyl numbering, if it applies.
disc-track. title.ext
)
$if($is_complete(),
$if($in(%media%,Vinyl),
%_musicbrainz_tracknumber%,
$if($gte(%totaldiscs%,2),
$pad(%discnumber%,2,0)-,)
$pad(%tracknumber%,2,0)
). %title%,
$if($in(%media%,Vinyl),
%_musicbrainz_tracknumber%,
$if($gt(%totaldiscs%,2),
$pad(%discnumber%,2,0)-,
)
$pad(%tracknumber%,2,0)
). %title%
)