Advanced-ish filenaming help needed(solved)

[DistractedFerret]

Hello!

I’m running into a bit of a snag, and it’s a little irritating to me; I’m hoping you experts might be able to help.

I’m currently using this script to rename and organize my files:

$replace($rreplace(
$if($eq(%albumartist%,Various Artists),[Various Artists],
$left($if2(%albumartistsort%,%artistsort%),1)
/
$left($rreplace($if2(%albumartistsort%,%artistsort%),; [^)]+,), 60))
/
$if(%date%,[$left(%date%,4)] )$left($replace(%album%,/,), 70)
$if($gt(%totaldiscs%,1),$if(%discnumber%, (Disc %discnumber%),),)
/
$left(%title%,120),[:?"_]+,), , )

It works like a charm…sort of. Bands like Ayreon and Aghast View are in folders “Ayreon” and “Aghast View”, while “The Beatles” are in “Beatles, The”. However, artists like Bryan Adams are being kicked over to “Adams, Bryan”. I’m sure it’s something simple I’m overlooking, any help is appreciated!

EDIT

Turns out, I just had to add a pair of $set tags to correct this:

$set(artistsort,$swapprefix(%artist%))
$set(albumartistsort,$swapprefix(%albumartist%))

Huge thanks to outsidecontext for the help!

[outsidecontext]

You are using the sort name (albumartistsort or artistsort). “The Beatles” would be sorted in a catalogue under “Beatles, The”, and “Bryan Adams” under “Adams, Bryan”.

If you only want to “The” bands sorted in differently but want to keep the person names in “Firstname Lastname” order then use the normal albumartist or artist variables together with the $swapprefix function:

$swapprefix($if2(%albumartist%,%artist%))

See also the following discussions for more details:

Problem with artists starting by "The..." in "Album Artist Sort Order" and "Artist Sort Order"

Just to clarify for others reading this: Having “Beatles, The” is the default for the sort name. The issue here is that the default sort name is not being used as in this case tdurivault wants to sort persons by first name, last name. So a script like the following is used: $set(artistsort,%artist%) To also fix the sorting for bands starting with The you can use the swapprefix function: $set(artistsort,$swapprefix(%artist%)) By default $swapprefix will move “The” and “A” at the beginning to …

How to move the word "The" to after the artist?

If all you want is handling The and A, but you don’t want to use the sort name in other cases, you can also use the $swapprefix function. $swapprefix(%artist%)

[DistractedFerret]

That fixed it perfectly, thanks so much!

$set(artistsort,$swapprefix(%artist%))
$set(albumartistsort,$swapprefix(%albumartist%))
$replace($rreplace(
$if($eq(%albumartist%,Various Artists),
[Various Artists],
$left($if2(%artistsort%,%albumartistsort%),1)/$left($rreplace($if2(%albumartistsort%,%artistsort%),; [^)]+,), 60))
/
$if(%date%,[$left(%date%,4)] )$left($replace(%album%,/,), 70)
$if($gt(%totaldiscs%,1),$if(%discnumber%, (Disc %discnumber%),),)
/
$left(%title%,120),[:?"_]+,), , )